
**Информирование пользователя. Работа с объектом «СообщениеПользователю»**

**Различные варианты и нюансы использования объекта СообщениеПользователю и другие способы информирования пользователя: без привязки к какой-либо форме и с выводом сообщения в отдельном окне.**

Объект «*СообщениеПользователю*» пришел на замену команды «*Сообщить*», которая использовалась в обычном интерфейсе, и перешла в управляемый. Команда удобна своей простотой и тем, что она, в отличии от других вариантов оповещения пользователя, доступна как на клиенте так и на сервере. На данный момент команда является устаревшей и ее не рекомендуется применять для управляемого интерфейса.

Объект «*СообщениеПользователю*» более громоздкий, но имеет ряд дополнительных возможностей, о которых и пойдет речь в данной статье. Объект можно использовать только для управляемого интерфейса.

Объект также можно использовать как на клиенте так и на сервере. Основным преимуществом перед командой «*Сообщить*», является возможность **привязки сообщений к реквизитам формы**. Дополнительно, при нажатии на текст сообщения, можно открывать новую форму с привязкой сообщения к ее реквизитам. Однако, следует понимать, что **основным назначением объекта является информирование об ошибках**, так как сообщение, привязанное к реквизитам формы всегда имеет заголовок  «*Ошибка*»:



Рассмотрим различные варианты использования объекта «*СообщениеПользователю*».

**Вариант 1. Вывод сообщения в текущую активную форму с привязкой к ее элементам**

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "Сообщение";

Сообщение.Поле = "Объект.Наименование";

Сообщение.Сообщить();

**Поле** – путь к реквизиту, к которому необходимо привязать сообщение. Путь к реквизитам объекта формы необходимо указывать задав ключевое слово «*Объект*». Путь к остальным реквизитам формы указывается просто, в виде наименования реквизита:

Сообщение.Поле = "РеквизитФормы";

Можно прикрепить сообщение к строке табличной части объекта:

Сообщение.Поле = "Объект.Товары[1].Номенклатура";

Следует иметь в виду,что**сообщение всегда выводится в текущую активную форму.** Даже в том случае, если сообщение формируется в другой форме, но она еще не открыта.

Например, при обработке события формы «*ПриОткрытии*» можно выполнить проверку некоторого условия и выводить сообщение об ошибке не открывая форму. Сообщение будет выведено в форму из которой выполнялось открытие новой формы.

**Вариант 2. Вывод сообщения в текущую активную форму с привязкой к элементам дополнительной формы**

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "Сообщение";

Сообщение.Поле = "Наименование";

Сообщение.КлючДанных = Объект.Склад;

Сообщение.ПутьКДанным = "Объект";

Сообщение.Сообщить();

**Поле** – наименование реквизита без указания ключевого слова «*Объект*».

**КлючДаных** – ссылка на объект дополнительной формы, к реквизиту которой требуется привязать сообщение. Система попробует найти открытую форму по значению стандартного параметра формы «*Ключ*». Если форма не будет найдена, будет открыта новая.

**ПутьКДанным** – имя основного реквизита формы, через который можно получить доступ к реквизитам объекта.

В данном варианте использования,**сообщение можно привязать только к реквизитам объекта формы**.

**Вариант 3. Вывод сообщения в форму, которая не является активной**

ПараметрыФормы = Новый Структура;

ПараметрыФормы.Вставить("Ключ", Объект.ОсновнойДоговор);

Форма = ОткрытьФорму("Справочник.Договоры.ФормаОбъекта",

ПараметрыФормы, ЭтаФорма);

Сообщение = Новый СообщениеПользователю;

Сообщение.ИдентификаторНазначения = Форма.УникальныйИдентификатор;

Сообщение.Текст = "Сообщение";

Сообщение.Поле = "Объект.Наименование";

Сообщение.Сообщить();

**УникальныйИдентификатор** – уникальный идентификатор формы, в которой будет выведено сообщение.

Сообщение может быть привязано как к реквизитам объекта, так и к остальным реквизитам формы.

**Вариант 4. Совмещение второго и третьего вариантов. Вывод сообщения не в текущую форму, с привязкой к реквизиту в третьей форме**

ПараметрыФормы = Новый Структура;

ПараметрыФормы.Вставить("Ключ", Объект.Контрагент);

Форма = ОткрытьФорму("Справочник.Контрагенты.ФормаОбъекта", ПараметрыФормы, ЭтаФорма);

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "Текст сообщения";

Сообщение.ИдентификаторНазначения = Форма.УникальныйИдентификатор;

Сообщение.Поле = "Наименование";

Сообщение.КлючДанных = Объект.Договор;

Сообщение.ПутьКДанным = "Объект";

Сообщение.Сообщить();

В результате вызова сообщения из формы документа, оно будет выведено в форме контрагента. При нажатии на текст сообщения, будет открыта форма договора, и сообщение будет привязано к реквизиту договора.

**Вариант 5. Вывод сообщения из модуля объекта**

Для вывода сообщения из модуля объекта, можно использовать следующий синтаксис:

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "Текст сообщения";

Сообщение.Поле = "Наименование";

Сообщение.КлючДанных = Ссылка;

Сообщение.ПутьКДанным = "Объект";

Сообщение.Сообщить();

Сообщение будет выведено и привязано к реквизитам корректно, причем параметры: «*КлючДанных*» и «*ПутьКДанным*» можно опустить, указав в параметре «*Поле*» полный путь к данным формы.

*Важно. Без указания параметров: «КлючДанных» и «ПутьКДанным» сообщение будет привязано к реквизитам формы только в том случае, если****форма объекта открыта и является активной****. Однако, код процедуры модуля объекта может быть выполнен и без открытия формы. В этом случае сообщение будет выведено в текущей активной форме. И, чтобы при нажатии на тексте сообщения, открывалась форма объекта с привязкой сообщения к реквизитам формы (например при проведении документа из формы списка), должны быть заполнены параметры: «КлючДанных» и «ПутьКДанным». Параметр «Поле» в этом случае, должен содержать наименование реквизита объекта.*

Также, как и на клиенте, есть возможность привязать сообщение к реквизитам формы объекта, который не является текущим. Для этого необходимо присвоить параметру «*КлючДанных*» ссылку на объект:

Сообщение.КлючДанных = ОсновнойДоговор;

В этом случае, будет открыта новая форма, по указанному ключу (ссылке) и сообщение будет привязано к ее реквизитам.

Однако, в модуле объекта, более корректно использовать метод объекта «*УстановитьДанные*» с указанием объекта, к которому требуется привязать сообщение:

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "Текст сообщения";

Сообщение.Поле = "Наименование";

Сообщение.УстановитьДанные(ЭтотОбъект);

Сообщение.Сообщить();

По своей сути, данный метод устанавливает значения для параметров: «*КлючДанных*» и «*ПутьКДанным*». Ключу данных будет присвоена ссылка на объект, а вот установка параметра «*ПутьКДанным*» происходит несколько сложнее. Дело в том, что работа с объектом может производится из разных форм. Имя основного реквизита формы, в общем случае, может отличатся от стандартного «*Объект*». **Метод «*УстановитьДанные*» определяет имя основного реквизита формы по установленному соответствию**. Причем, при записи объекта это соответствие устанавливается автоматически. В тех случаях, когда автоматического сопоставления нет, его необходимо указать явно с помощью метода «*УстановитьСоответствиеОбъектаИРеквизитаФормы*». Например, необходимо выполнить какие-либо действия с объектом, привязанным к текущей форме, и вывести в процессе этих действий сообщение:

//Серверная процедура в модуле  формы

&НаСервере

Процедура ОбработкаОбъекта()

       КонтрагентОбъект = ДанныеФормыВЗначение(Объект, Тип("СправочникОбъект.Контрагенты"));

       УстановитьСоответствиеОбъектаИРеквизитаФормы (КонтрагентОбъект, "Объект");

       КонтрагентОбъект.ВыполнитьРаботуСОбъектом();

КонецПроцедуры

//Процедура в модуле объекта

Процедура ВыполнитьРаботуСОбъектом() Экспорт

      ……

      Сообщение = Новый СообщениеПользователю;

      Сообщение.Текст = "Текст сообщения";

      Сообщение.Поле = "Наименование";

      Сообщение.УстановитьДанные(ЭтотОбъект);


      Сообщение.Сообщить();

КонецПроцедуры

**Оповещение пользователя без привязки к конкретной форме**

Следует иметь в виду, что сообщения, выведенные командой «Сообщить» или через объект «*СообщениеПользователю*» **всегда привязаны к какой-либо форме**. Если после вывода сообщения форма закрывается, пользователь не сможет его прочитать. В данном случае удобнее использовать другие методы глобального контекста: «*ПоказатьОповещениеПользователю*» или «Состояние». **Вызов методов возможен только на клиенте**.

Метод «*ПоказатьОповещениеПользователю*» выводит всплывающее оповещение в нижний часть экрана, которое не привязано к какой-либо открытой форме:



Синтаксис метода в справке:

ПоказатьОповещениеПользователя(<Текст>,

<ДействиеПриНажатии>,

<Пояснение>,

<Картинка>,

<СтатусОповещенияПользователя>,

<КлючУникальности>)

Первый параметр «*Текст*» вводит в заблуждение, на самом деле – это заголовок окна оповещения.

Второй параметр «*ДействиеПриНажатии*» может содержать либо навигационную ссылку, по которой необходимо перейти при нажатии на сообщении, либо описание процедуры оповещения.


Параметр «*Пояснение*» - это как раз текст оповещения.

Дополнительно, есть возможность вывести картинку, указать важность оповещения и задать ключ уникальности для поиска уже открытых оповещений.

*Примечание. Следует использовать данный метод для информационных, не особенно важных сообщения, так как они исчезают самостоятельно, без каких либо действий со стороны пользователя.*

Команда «*Состояние*» выводит информацию в специальную панель состояния. Ее следует использовать для информирования пользователя о ходе выполнения кого либо действия. Дополнительно есть возможность показать прогресс выполнения:

Состояние(«Выполнение операции, 50, «Операция выполняется»);



**Вывод сообщения пользователю в отдельном окне**

В некоторых случаях требуется вывести сообщение пользователю в отдельном окне. Для этой цели можно использовать как собственную разработанную форму, так и не модальный метод глобального контекста «*ПоказатьПредупрежедение*». (В отличие от модальных методов, данный не ожидает выполнения действия с формой, а продолжает выполнение программного кода). **Вызов метода возможен только на клиенте**.

В качестве первого параметра необходимо указать процедуру - описание оповещения. В качестве второго – текст выводимого сообщения. Причем, в качестве текста сообщения можно использовать форматированную строку. Это позволяет вывести в тексте сообщения ссылку на какой-либо объект:

СтрокаСообщения = Новый ФорматированнаяСтрока(НовыйДоговор.Наименование,,,,

ПолучитьНавигационнуюСсылку(НовыйДоговор.Ссылка));

ТекстСообщения = Новый ФорматированнаяСтрока("Создан новый договор: """, СтрокаСообщения,"""");

ОписаниеОповещения = новый ОписаниеОповещения("ПредупрежедениеЗавершение",ЭтаФорма);

ПоказатьПредупреждение(ОписаниеОповещения, ТекстСообщения,, "Заголовок сообщения");

&НаКлиенте

Процедура ПредупрежедениеЗавершение(Параметры) Экспорт

       //Обработка закрытия предупреждения

КонецПроцедуры

